plugins {
    alias(libs.plugins.kotlin.multiplatform)
    alias(libs.plugins.kotlin.serialization)
}

kotlin {
    jvmToolchain(21)

    // KMP-модуль с ядром механики toolsets: реестр, диспетчер, встроенные тулы
    // enable_toolset/disable_toolset. Не зависит от :standalone — может быть
    // переиспользован в Android-сборке и в любом другом LiteTool-агенте.
    jvm()
    macosX64()
    macosArm64()
    iosX64()
    iosArm64()
    iosSimulatorArm64()
    linuxX64()
    linuxArm64()
    mingwX64()

    sourceSets {
        commonMain.dependencies {
            // :storage-core — для StorageBundle в ToolsetContext (commit 5+)
            api(project(":storage-core"))

            // litert-kmp: LiteTool интерфейс (sync describe/invoke)
            api(libs.litert.api)

            api(libs.kotlinx.coroutines.core)
            api(libs.kotlinx.serialization.json)
        }
        jvmMain.dependencies {
            // runBlocking для SyncLiteTool обёртки (LiteTool.invoke — sync)
            implementation(libs.kotlin.logging)
        }
        commonTest.dependencies {
            implementation(kotlin("test"))
            implementation(libs.kotlinx.coroutines.test)
        }
    }
}