plugins {
    alias(libs.plugins.kotlin.multiplatform)
    alias(libs.plugins.kotlin.serialization)
}

kotlin {
    jvmToolchain(21)

    // Только то, что нам реально нужно: JVM + 5 desktop-native. iOS не входит —
    // :client не имеет смысла на iOS, а :agentik-cli использует :client и тоже
    // без iOS. См. agentik-cli/build.gradle.kts.
    jvm()
    listOf(
        macosX64(),
        macosArm64(),
        linuxX64(),
        linuxArm64(),
        mingwX64(),
    )

    sourceSets {
        commonMain.dependencies {
            api(project(":proto"))
            api(project(":event-store"))

            api(libs.ktor.client.core)
            implementation(libs.ktor.client.content.negotiation)
            implementation(libs.ktor.serialization.kotlinx.json)

            implementation(libs.kotlinx.coroutines.core)
            implementation(libs.kotlinx.serialization.core)
            implementation(libs.kotlinx.serialization.json)
        }
        commonTest.dependencies {
            implementation(libs.kotlin.test)
            implementation(libs.kotlinx.coroutines.test)
            implementation(libs.ktor.server.core)
            implementation(libs.ktor.server.test.host)
            implementation(libs.ktor.client.content.negotiation)
            implementation(libs.ktor.client.cio)
            implementation(libs.ktor.server.cio)
            implementation(libs.ktor.server.sse)
        }
        jvmTest.dependencies {
            implementation("junit:junit:4.13.2")
        }
    }

    // :client — это библиотека, не executable. Native-бинари объявляются
    // в :agentik-cli (он зависит от :client и реально предоставляет main).
}