import org.gradle.api.publish.maven.MavenPublication

plugins {
    alias(libs.plugins.kotlin.multiplatform) apply false
    alias(libs.plugins.kotlin.serialization) apply false
}

allprojects {
    group = "pw.binom.agui"
}

subprojects {
    plugins.withId("maven-publish") {
        extensions.configure<PublishingExtension>("publishing") {
            publications.withType<MavenPublication>().configureEach {
                pom {
                    name.set(project.name)
                    description.set("AG-UI (Agent-User Interface) protocol implementation")
                    url.set("https://github.com/ag-ui-protocol/ag-ui")
                }
            }
            repositories {
                maven {
                    name = "caffeine"
                    url = uri("http://nexus.xx/repository/caffeine/")
                    isAllowInsecureProtocol = true
                    credentials {
                        username = (project.findProperty("binom.repo.user") as String?) ?: System.getenv("BINOM_REPO_USER").orEmpty()
                        password = (project.findProperty("binom.repo.password") as String?) ?: System.getenv("BINOM_REPO_PASSWORD").orEmpty()
                    }
                }
            }
        }
    }
}